CFScript

CFScript is an extension of CFML on the ColdFusion platform. CFScript resembles JavaScript. Some ColdFusion developers prefer it since it has less visual and typographical overhead than ordinary CFML.^{[clarification needed]}

Usage

Unless it is within a pure script-based ColdFusion Component, all CFScript code must be contained within a CFScript tag pair as follows:

<cfscript>
xParam = 115;
yParam = 200;
color = 'FFCC99';
</cfscript>

A simple example of a function:

<cfscript>
function Sum(a, b) {
    var sum = a + b;
    return sum;
}
</cfscript>

A simple example of a component in CFScript, containing two functions:

component {
    public void function foo() {
        WriteOutput("Method foo() called<br/>");
    }

    public function getString() {
        var x = "hello";
        return x;
    }
}

ColdFusion 11, Railo 4.1+, and Lucee 4.5+ both do their best to fully support cf tags in CFScript. While there may not be direct substitutions for all tags, it is often still possible to achieve the results of a tag in script, but via a different syntax. For example, this is how to get a query into a variable in CFSCRIPT without writing a UDF:

<cfscript>
qGetData = new Query();
qGetData.setDataSource('#Application.datasource#');
qGetData.setSQL('SELECT column1, column2 FROM table WHERE 1');
qDateResult = qGetData.Execute().getResult();
</cfscript>

Syntax

Since ColdFusion 8, CFScript has supported syntax abbreviations that are common in many other programming languages, such as "++", "<=" and "+=".

Arithmetic operators

Comments

CFScript has two forms of comments: single line and multiline.

// This is a single-line comment.
// This is a second single-line comment.

/* This is a multiline comment.
   You do not need to start each line with a comment indicator.
   This line is the last line in the comment. */

Try / catch

try {
    throw(message="Oops", detail="xyz");
} catch (any e) {
    WriteOutput("Error: " & e.message);
    rethrow;
} finally {
    WriteOutput("I run even if no error");
}

Switch statement

switch (car) {
    case "Nissan":
         WriteOutput("I own a Nissan");
         break;
    case "Toyota":
         WriteOutput("I own a Toyota");
         break;
    default:
         WriteOutput("I'm exotic");
}

Looping

For loop

for (i=1; i <= ArrayLen(array); i=i+1) {
    WriteOutput(array[i]);
}

FOR IN Loop

struct = StructNew();
struct.one = "1";
struct.two = "2";
for (key in struct) {
    WriteOutput(key);
}
//OUTPUTS onetwo

While loop

x = 0;
while (x < 5) {
    x = x + 1;
    WriteOutput(x);
}
// Outputs: 12345

Do / while loop

x = 0;
do {
    x = x + 1;
    WriteOutput(x);
} while (x <= 0);
// Outputs: 1

Looping over an array

for (item in array) {
    doSomething(item);
}

Differences from JavaScript

Although CFScript and JavaScript are similar, they have several key differences. The following list identifies CFScript features that differ from JavaScript:

CFScript uses ColdFusion expression, which are not a superset or a subset of JavaScript expressions. In particular, ColdFusion expressions do not support bitwise operators, and the ColdFusion MOD or % operator operates differently from the corresponding JavaScript % operator: In ColdFusion, the operator does integer arithmetic and ignores fractional parts. ColdFusion expressions also support the EQV, IMP, CONTAINS, and DOES NOT CONTAIN operators that are not supported in JavaScript.
Variable declarations (var keyword) are only used in user-defined functions and threads.
CFScript is not case sensitive.
All statements end with a semicolon, and line breaks in the code are ignored.
Assignments are statements, not expressions, and therefore cannot be used in situations that require evaluating the assignment operation.
JavaScript objects, such as window and document, are not available.
Only the ColdFusion server processes CFScript. There is no client-side CFScript.